[Yanel-commits] rev 22694 - in
public/yanel/trunk/src/realms/test/yanel: data/xslt rti rti/jmeter
josias at wyona.com
josias at wyona.com
Thu Feb 15 21:57:58 CET 2007
Author: josias
Date: 2007-02-15 21:57:56 +0100 (Thu, 15 Feb 2007)
New Revision: 22694
Added:
public/yanel/trunk/src/realms/test/yanel/data/xslt/jmeter-results-detail-report.xsl
public/yanel/trunk/src/realms/test/yanel/rti/jmeter/
public/yanel/trunk/src/realms/test/yanel/rti/jmeter/jmeter-results.yanel-rti
public/yanel/trunk/src/realms/test/yanel/rti/jmeter/jtl-rc-template.yanel-rc
public/yanel/trunk/src/realms/test/yanel/rti/map.rc-map
Modified:
public/yanel/trunk/src/realms/test/yanel/data/xslt/global.xsl
Log:
added rc map for the jmeter test files and added rc files and xslts to display the jmeter test results. see bug #5192, thanks to Simon
Modified: public/yanel/trunk/src/realms/test/yanel/data/xslt/global.xsl
===================================================================
--- public/yanel/trunk/src/realms/test/yanel/data/xslt/global.xsl 2007-02-15 20:55:20 UTC (rev 22693)
+++ public/yanel/trunk/src/realms/test/yanel/data/xslt/global.xsl 2007-02-15 20:57:56 UTC (rev 22694)
@@ -108,6 +108,7 @@
<br/>  <a href="{$yarep.back2realm}testing-control.html">Testing Control</a>
<br/>  <a href="{$yarep.back2realm}test-results-archive/">Test Results Archive</a>
<br/>  <a href="{$yarep.back2realm}testing-times.html">Time Analyze</a>
+ <br/>  <a href="{$yarep.back2realm}jmeter/jmeter-results/">JMeter Results</a>
<br/> <b><a href="{$yarep.back2realm}use-cases/">Use Cases</a></b>
<br/>
</xsl:template>
Added: public/yanel/trunk/src/realms/test/yanel/data/xslt/jmeter-results-detail-report.xsl
===================================================================
--- public/yanel/trunk/src/realms/test/yanel/data/xslt/jmeter-results-detail-report.xsl 2007-02-15 20:55:20 UTC (rev 22693)
+++ public/yanel/trunk/src/realms/test/yanel/data/xslt/jmeter-results-detail-report.xsl 2007-02-15 20:57:56 UTC (rev 22694)
@@ -0,0 +1,404 @@
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+ xmlns="http://www.w3.org/1999/xhtml"
+ xmlns:xhtml="http://www.w3.org/1999/xhtml"
+ version="1.0">
+
+ <xsl:output method="xhtml" encoding="UTF-8"/>
+
+ <!-- Defined parameters (overrideable) -->
+ <xsl:param name="showData" select="'N'"/>
+
+ <xsl:template match="testResults">
+ <html>
+ <head>
+ <title>Load Test Results</title>
+ <style type="text/css">
+ body {
+ font:normal 68% verdana,arial,helvetica;
+ color:#000000;
+ }
+ table tr td, table tr th {
+ font-size: 68%;
+ }
+ table.details tr th{
+ font-weight: bold;
+ text-align:left;
+ background:#a6caf0;
+ white-space: nowrap;
+ }
+ table.details tr td{
+ background:#eeeee0;
+ white-space: nowrap;
+ }
+ h1 {
+ margin: 0px 0px 5px; font: 165% verdana,arial,helvetica
+ }
+ h2 {
+ margin-top: 1em; margin-bottom: 0.5em; font: bold 125% verdana,arial,helvetica
+ }
+ h3 {
+ margin-bottom: 0.5em; font: bold 115% verdana,arial,helvetica
+ }
+ .Failure {
+ font-weight:bold; color:red;
+ }
+
+
+ img
+ {
+ border-width: 0px;
+ }
+
+ .expand_link
+ {
+ position=absolute;
+ right: 0px;
+ width: 27px;
+ top: 1px;
+ height: 27px;
+ }
+
+ .page_details
+ {
+ display: none;
+ }
+
+ .page_details_expanded
+ {
+ display: block;
+ display/* hide this definition from IE5/6 */: table-row;
+ }
+ </style>
+ <script language="JavaScript"><![CDATA[
+ function expand(details_id)
+ {
+
+ document.getElementById(details_id).className = "page_details_expanded";
+ }
+
+ function collapse(details_id)
+ {
+
+ document.getElementById(details_id).className = "page_details";
+ }
+
+ function change(details_id)
+ {
+ if(document.getElementById(details_id+"_image").src.match("expand"))
+ {
+ document.getElementById(details_id+"_image").src = "../../img/collapse.jpg";
+ expand(details_id);
+ }
+ else
+ {
+ document.getElementById(details_id+"_image").src = "../../img/expand.jpg";
+ collapse(details_id);
+ }
+ }
+ ]]></script>
+ </head>
+ <body>
+ <xsl:call-template name="pageHeader"/>
+ <xsl:call-template name="summary"/>
+ <hr size="1" width="95%" align="left"/>
+ <xsl:call-template name="pagelist"/>
+ <hr size="1" width="95%" align="left"/>
+ <xsl:call-template name="detail"/>
+ </body>
+ </html>
+ </xsl:template>
+
+ <xsl:template name="pageHeader">
+ <h1>Load Test Results</h1>
+ <table width="100%">
+ <tr>
+ <td align="left"/>
+ <td align="right">Designed for use with <a
+ href="http://jakarta.apache.org/jmeter">JMeter</a> and <a href="http://ant.apache.org">Ant</a>.</td>
+ </tr>
+ </table>
+ <hr size="1"/>
+ </xsl:template>
+
+ <xsl:template name="summary">
+ <h2>Summary</h2>
+ <table class="details" border="0" cellpadding="5" cellspacing="2" width="95%">
+ <tr valign="top">
+ <th>Tests</th>
+ <th>Failures</th>
+ <th>Success Rate</th>
+ <th>Average Time</th>
+ <th>Min Time</th>
+ <th>Max Time</th>
+ </tr>
+ <tr valign="top">
+ <xsl:variable name="allCount" select="count(/testResults/sampleResult)"/>
+ <xsl:variable name="allFailureCount" select="count(/testResults/sampleResult[attribute::success='false'])"/>
+ <xsl:variable name="allSuccessCount" select="count(/testResults/sampleResult[attribute::success='true'])"/>
+ <xsl:variable name="allSuccessPercent" select="$allSuccessCount div $allCount"/>
+ <xsl:variable name="allTotalTime" select="sum(/testResults/sampleResult/@time)"/>
+ <xsl:variable name="allAverageTime" select="$allTotalTime div $allCount"/>
+ <xsl:variable name="allMinTime">
+ <xsl:call-template name="min">
+ <xsl:with-param name="nodes" select="/testResults/sampleResult/@time"/>
+ </xsl:call-template>
+ </xsl:variable>
+ <xsl:variable name="allMaxTime">
+ <xsl:call-template name="max">
+ <xsl:with-param name="nodes" select="/testResults/sampleResult/@time"/>
+ </xsl:call-template>
+ </xsl:variable>
+ <xsl:attribute name="class">
+ <xsl:choose>
+ <xsl:when test="$allFailureCount > 0">Failure</xsl:when>
+ </xsl:choose>
+ </xsl:attribute>
+ <td>
+ <xsl:value-of select="$allCount"/>
+ </td>
+ <td>
+ <xsl:value-of select="$allFailureCount"/>
+ </td>
+ <td>
+ <xsl:call-template name="display-percent">
+ <xsl:with-param name="value" select="$allSuccessPercent"/>
+ </xsl:call-template>
+ </td>
+ <td>
+ <xsl:call-template name="display-time">
+ <xsl:with-param name="value" select="$allAverageTime"/>
+ </xsl:call-template>
+ </td>
+ <td>
+ <xsl:call-template name="display-time">
+ <xsl:with-param name="value" select="$allMinTime"/>
+ </xsl:call-template>
+ </td>
+ <td>
+ <xsl:call-template name="display-time">
+ <xsl:with-param name="value" select="$allMaxTime"/>
+ </xsl:call-template>
+ </td>
+ </tr>
+ </table>
+ </xsl:template>
+
+ <xsl:template name="pagelist">
+ <h2>Pages</h2>
+ <table class="details" border="0" cellpadding="5" cellspacing="2" width="95%">
+ <tr valign="top">
+ <th>URL</th>
+ <th>Tests</th>
+ <th>Failures</th>
+ <th>Success Rate</th>
+ <th>Average Time</th>
+ <th>Min Time</th>
+ <th>Max Time</th>
+ <th/>
+ </tr>
+ <xsl:for-each select="/testResults/sampleResult[not(@label = preceding::*/@label)]">
+ <xsl:variable name="label" select="@label"/>
+ <xsl:variable name="count" select="count(../sampleResult[@label = current()/@label])"/>
+ <xsl:variable name="failureCount" select="count(../sampleResult[@label = current()/@label][attribute::success='false'])"/>
+ <xsl:variable name="successCount" select="count(../sampleResult[@label = current()/@label][attribute::success='true'])"/>
+ <xsl:variable name="successPercent" select="$successCount div $count"/>
+ <xsl:variable name="totalTime" select="sum(../sampleResult[@label = current()/@label]/@time)"/>
+ <xsl:variable name="averageTime" select="$totalTime div $count"/>
+ <xsl:variable name="minTime">
+ <xsl:call-template name="min">
+ <xsl:with-param name="nodes" select="../sampleResult[@label = current()/@label]/@time"/>
+ </xsl:call-template>
+ </xsl:variable>
+ <xsl:variable name="maxTime">
+ <xsl:call-template name="max">
+ <xsl:with-param name="nodes" select="../sampleResult[@label = current()/@label]/@time"/>
+ </xsl:call-template>
+ </xsl:variable>
+ <tr valign="top">
+ <xsl:attribute name="class">
+ <xsl:choose>
+ <xsl:when test="$failureCount > 0">Failure</xsl:when>
+ </xsl:choose>
+ </xsl:attribute>
+ <td>
+ <xsl:if test="$failureCount > 0">
+ <a>
+ <xsl:attribute name="href">#<xsl:value-of select="$label"/>
+ </xsl:attribute>
+ <xsl:value-of select="$label"/>
+ </a>
+ </xsl:if>
+ <xsl:if test="0 >= $failureCount">
+ <xsl:value-of select="$label"/>
+ </xsl:if>
+ </td>
+ <td>
+ <xsl:value-of select="$count"/>
+ </td>
+ <td>
+ <xsl:value-of select="$failureCount"/>
+ </td>
+ <td>
+ <xsl:call-template name="display-percent">
+ <xsl:with-param name="value" select="$successPercent"/>
+ </xsl:call-template>
+ </td>
+ <td>
+ <xsl:call-template name="display-time">
+ <xsl:with-param name="value" select="$averageTime"/>
+ </xsl:call-template>
+ </td>
+ <td>
+ <xsl:call-template name="display-time">
+ <xsl:with-param name="value" select="$minTime"/>
+ </xsl:call-template>
+ </td>
+ <td>
+ <xsl:call-template name="display-time">
+ <xsl:with-param name="value" select="$maxTime"/>
+ </xsl:call-template>
+ </td>
+ <td align="center">
+ <a href="">
+ <xsl:attribute name="href">
+ <xsl:text/>javascript:change('page_details_<xsl:value-of select="position()"/>')</xsl:attribute>
+ <img src="../../img/expand.jpg" alt="expand/collapse">
+ <xsl:attribute name="id">
+ <xsl:text/>page_details_<xsl:value-of select="position()"/>_image</xsl:attribute>
+ </img>
+ </a>
+ </td>
+ </tr>
+ <tr class="page_details">
+ <xsl:attribute name="id">
+ <xsl:text/>page_details_<xsl:value-of select="position()"/>
+ </xsl:attribute>
+ <td colspan="8" bgcolor="#FF0000">
+ <div align="center">
+ <b>Details for Page "<xsl:value-of select="$label"/>"</b>
+ <table bordercolor="#000000" border="1" cellpadding="0"
+ cellspacing="0" width="95%">
+ <tr>
+ <th>Thread</th>
+ <th>Iteration</th>
+ <th>Time</th>
+ <th>Success</th>
+ <!--
+ itterations = position() - thread stuff
+ time="312"
+ timeStamp="1053622047640"
+ responseMessage="OK"
+ threadName="Thread Group-1"
+ dataType="text"
+ label="/CansysAandA/processAuthentication.do"
+ success="true"
+ -->
+ </tr>
+ <xsl:for-each select="../sampleResult[@label = $label and @threadName != $label]">
+ <tr>
+ <td>
+ <xsl:value-of select="@threadName"/>
+ </td>
+ <td>
+ <xsl:value-of select="position()"/>
+ </td>
+ <td>
+ <xsl:value-of select="@time"/>ms</td>
+ <td>
+ <xsl:value-of select="@success"/>
+ </td>
+ </tr>
+ </xsl:for-each>
+ </table>
+ </div>
+ </td>
+ </tr>
+ </xsl:for-each>
+ </table>
+ </xsl:template>
+
+ <xsl:template name="detail">
+ <xsl:variable name="allFailureCount" select="count(/testResults/sampleResult[attribute::success='false'])"/>
+ <xsl:if test="$allFailureCount > 0">
+ <h2>Failure Detail</h2>
+ <xsl:for-each select="/testResults/sampleResult[not(@label = preceding::*/@label)]">
+ <xsl:variable name="failureCount" select="count(../sampleResult[@label = current()/@label][attribute::success='false'])"/>
+ <xsl:if test="$failureCount > 0">
+ <h3>
+ <xsl:value-of select="@label"/>
+ <a>
+ <xsl:attribute name="name">
+ <xsl:value-of select="@label"/>
+ </xsl:attribute>
+ </a>
+ </h3>
+ <table class="details" border="0" cellpadding="5" cellspacing="2" width="95%">
+ <tr valign="top">
+ <th>Response</th>
+ <th>Failure Message</th>
+ <xsl:if test="$showData = 'y'">
+ <th>Response Data</th>
+ </xsl:if>
+ </tr>
+ <xsl:for-each select="/testResults/sampleResult[@label = current()/@label][attribute::success='false']">
+ <tr>
+ <td>
+ <xsl:value-of select="@responseCode"/> - <xsl:value-of select="@responseMessage"/>
+ </td>
+ <td>
+ <xsl:value-of select="assertionResult/@failureMessage"/>
+ </td>
+ <xsl:if test="$showData = 'y'">
+ <td>
+ <xsl:value-of select="./binary"/>
+ </td>
+ </xsl:if>
+ </tr>
+ </xsl:for-each>
+ </table>
+ </xsl:if>
+ </xsl:for-each>
+ </xsl:if>
+ </xsl:template>
+
+ <xsl:template name="min">
+ <xsl:param name="nodes" select="/.."/>
+ <xsl:choose>
+ <xsl:when test="not($nodes)">NaN</xsl:when>
+ <xsl:otherwise>
+ <xsl:for-each select="$nodes">
+ <xsl:sort data-type="number"/>
+ <xsl:if test="position() = 1">
+ <xsl:value-of select="number(.)"/>
+ </xsl:if>
+ </xsl:for-each>
+ </xsl:otherwise>
+ </xsl:choose>
+ </xsl:template>
+
+ <xsl:template name="max">
+ <xsl:param name="nodes" select="/.."/>
+ <xsl:choose>
+ <xsl:when test="not($nodes)">NaN</xsl:when>
+ <xsl:otherwise>
+ <xsl:for-each select="$nodes">
+ <xsl:sort data-type="number" order="descending"/>
+ <xsl:if test="position() = 1">
+ <xsl:value-of select="number(.)"/>
+ </xsl:if>
+ </xsl:for-each>
+ </xsl:otherwise>
+ </xsl:choose>
+ </xsl:template>
+
+ <xsl:template name="display-percent">
+ <xsl:param name="value"/>
+ <xsl:value-of select="format-number($value,'0.00%')"/>
+ </xsl:template>
+
+ <xsl:template name="display-time">
+ <xsl:param name="value"/>
+ <xsl:value-of select="format-number($value,'0 ms')"/>
+ </xsl:template>
+
+</xsl:stylesheet>
Property changes on: public/yanel/trunk/src/realms/test/yanel/data/xslt/jmeter-results-detail-report.xsl
___________________________________________________________________
Name: svn:eol-style
+ native
Added: public/yanel/trunk/src/realms/test/yanel/rti/jmeter/jmeter-results.yanel-rti
===================================================================
--- public/yanel/trunk/src/realms/test/yanel/rti/jmeter/jmeter-results.yanel-rti 2007-02-15 20:55:20 UTC (rev 22693)
+++ public/yanel/trunk/src/realms/test/yanel/rti/jmeter/jmeter-results.yanel-rti 2007-02-15 20:57:56 UTC (rev 22694)
@@ -0,0 +1,2 @@
+<{http://www.wyona.org/yanel/resource/1.0}directory/>
+xslt:/xslt/global.xsl
Added: public/yanel/trunk/src/realms/test/yanel/rti/jmeter/jtl-rc-template.yanel-rc
===================================================================
--- public/yanel/trunk/src/realms/test/yanel/rti/jmeter/jtl-rc-template.yanel-rc 2007-02-15 20:55:20 UTC (rev 22693)
+++ public/yanel/trunk/src/realms/test/yanel/rti/jmeter/jtl-rc-template.yanel-rc 2007-02-15 20:57:56 UTC (rev 22694)
@@ -0,0 +1,8 @@
+<?xml version="1.0"?>
+
+<yanel:resource-config xmlns:yanel="http://www.wyona.org/yanel/rti/1.0">
+ <yanel:rti name="xml" namespace="http://www.wyona.org/yanel/resource/1.0"/>
+
+ <yanel:property name="mime-type" value="application/xhtml+xml"/>
+ <yanel:property name="xslt" value="/xslt/jmeter-results-detail-report.xsl"/>
+</yanel:resource-config>
\ No newline at end of file
Added: public/yanel/trunk/src/realms/test/yanel/rti/map.rc-map
===================================================================
--- public/yanel/trunk/src/realms/test/yanel/rti/map.rc-map 2007-02-15 20:55:20 UTC (rev 22693)
+++ public/yanel/trunk/src/realms/test/yanel/rti/map.rc-map 2007-02-15 20:57:56 UTC (rev 22694)
@@ -0,0 +1,6 @@
+<?xml version="1.0"?>
+<rc-map>
+
+<matcher pattern="**/*/*.jtl" rcpath="/jmeter/jtl-rc-template.yanel-rc"/>
+
+</rc-map>
\ No newline at end of file
More information about the Yanel-commits
mailing list